Count Fibula

Part 3 - New Actions

Fullscoring is an action out of world. Understand "full" and "fullscore" and "full score" as fullscoring.

Report fullscoring:

say "You've considered [score in words] total house configuration[s] out of a possible [maximum score in words] before finishing the episode.";

carry out the Reciting Endings activity.

Abouting is an action out of world. Understand "about" and "info" as abouting.

Report abouting: say "Just to set your expectations, [italic type]This Old Haunted House[roman type] requires only a limited subset of commands to be completed. As host, it's your job to [bold type]WAIT[roman type] (or type [bold type]Z[roman type]) until Han describes the proposals that Hoary and Terry are presenting to you. Once they do, [bold type]TAKE[roman type] one of those proposals[one of][or] (or [bold type]TAKE NEITHER[roman type] to leave the room with minimal decoration, if you'd prefer for some reason)[stopping]. Finally, you can [bold type]LEAVE[roman type] whenever your producer has captured a satisfying outcome during the day's taping. (If you want your producer to recap the options for the current room, just [bold type]TALK[roman type] to him.) To track your progress, you can use [bold type]SCORE[roman type] for a simple count of the configurations you've discovered, or [bold type]FULLSCORE[roman type] for a more detailed list[one of].[or]. You may also prefer to obtain [bold type]HELP[roman type], get a [bold type]HINT[roman type], or if all else fails, you can [bold type]SUMMON[roman type] a Marketing analyst zombie: you can skip the grunt-work, and they'll always get you a configuration you haven't found yet, though there's no guarantee it's a good one.[stopping][line break]Please send me any feedback, bug reports, or transcripts to [bold type]count.fibula@gmail.com[roman type]. This is version 2 of the game, which was updated with new source remarks and public source code.". [% The smart thing to do would be to refer to the version number from within the ABOUT text. I didn't do that.]

Crediting is an action out of world. Understand "credits" and "testers" as crediting.

Report crediting: say "This game makes use of the following extensions:[line break][bold type][the complete list of extension credits][roman type][line break]I'd like to thank the [bold type]ECTOCOMP ORGANIZERS[roman type] for putting together the 2022 competition.[if the score is greater than 0] The bathroom set-piece was invented by [bold type]Chris Jones[roman type] for [italic type]Cragne Manor[roman type].[otherwise] One particular set-piece was borrowed from [bold type]another author[roman type] who I will not name at this moment.[end if] [paragraph break]Additional thanks go to [bold type]nettle[roman type], [bold type]Gate88[roman type], and [bold type]Zaratustra[roman type] for testing the original game from which this game was adapted.Similarly, if you find any bugs or would like to send me a transcript of your play session, please email [bold type]count.fibula@gmail.com[roman type].[paragraph break](You may also wish to read the [bold type]DEDICATION[roman type].)".

Dedication is an action out of world. Understand "dedication" as dedication.

Report dedication: say "[italic type][Story title][roman type] is dedicated to [bold type]you[roman type], since you decided to play it! Thank you!"

Controversion is an action out of world. Understand "controversion" as controversion.

Report controversion: say "[italic type][Story title][roman type] is controverted to [bold type]the developers of Final Fantasy XIV[roman type], whose work ensured this game was released much later than it might otherwise have been."

Helping is an action out of world. Understand "help" and "walkthrough" and "walkthru" as helping.

Report helping: say "Han's plan for the episode is that, for each room in the house, the boo-thers will present you with two proposals. While they're not opposites, they are mutually[one of] exclusive. Regardless[or] exclusive. (However, you're not [italic type]required[roman type] to choose one of the described proposals; you could instead select neither. This is necessary to obtain every potential house configuration result, but that's not necessarily optimal.) Regardless[stopping] of your selection, you'll proceed to the next room, and another pair of proposals. The selections you make will determine the overall tone of the house, and Han will conclude with an assessment of its appeal to [italic type]This Old Haunted House[roman type]'s audience. Obviously, you need to find the best overall assessment, but there are multiple ways of achieving that result.[paragraph break]Frequent players may prefer to abbreviate commands; for example, shorten 'TAKE HOARY'S PROPOSAL' to simply 'HOARY'.[paragraph break]If you're stuck getting the same assessments repeatedly, you can ask for a HINT[one of][or] or just SUMMON an analyst zombie to skip the proposals and obtain a random assessment instead[stopping]. You can TALK TO HAN to have him recap the options for the current room."

[% In "THE EXIGENT SEASONS", I wanted the order of crises the player encountered to be presented in a random order, but this made less sense for the geographic concerns presented by "This Old Haunted House". XYZZY lets the player switch between these behaviors. I'm not sure why I thought it was important to prevent the toggle from occurring until every room had been seen once, though.]

A person can be ordered, chaotic, or indeterminate. A person is usually indeterminate.

Xyzzying is an action out of world. Understand "xyzzy" as xyzzying. Understand "plugh" as xyzzying. Understand "plover" as xyzzying.

Carry out xyzzying:

if the score is 0:

say "[one of]Oh ho, you've thought of a frightful magical word! I bet signing something so unexpected will give Han a real jump, but you'll need to find the right time to deploy it. Better get some more filming done before you try it again[or]Soon, but not yet[stopping].";

otherwise:

if the player is ordered:

now the player is chaotic;

say "Han [one of]jumps, dropping[or]drops[stopping] his notes in a big pile. '[one of]Look what you made me do! Now the scenes are going to be all out of order. It's fine, but editing this thing's going to be a real beast, you j[or]J[stopping]erk.'";

otherwise:

now the player is ordered;

say "The ghosts seem perplexed by your wiggling phalanges, but Han just ignores you, taking the time to get his scene notes back in order.".

[% As I've documented elsewhere, these games originally started life as a "Which Magic: the Gathering color(s) are you?" quiz I'd designed around 2007. I found testing the endings a lot easier if could cross-reference choices and outcomes with the original color quiz, so I added magic words to accomplish that, and I left the command in the final version of the games as something to mention in the AMUSING text.]

A person can be drowsy or undrowsy. When play begins, now the player is drowsy.

Invoking is an action out of world. Understand "presto" as invoking. Understand "presto changeo" as invoking. Understand "abracadabra" as invoking. Understand "yzzyx" as invoking. Understand "hgulp" as invoking. Understand "revolp" as invoking. Understand "invoke name" as invoking. Understand "alakazam" as invoking. Understand "abra cadabra" as invoking. Understand "hocus pocus" as invoking. Understand "hey presto" as invoking. Understand "please" as invoking. Understand "thank you" as invoking.

Carry out invoking:

if the player is mundane:

now the player is magical;

say "Han [one of]startles you with a shout:[or]shouts:[stopping] 'Okay, folks, time to turn on our color-coding!'";

otherwise:

now the player is mundane;

say "Han shouts again: 'Color-coding is over!'[one of][or] With no other crew present, it's not clear who he's addressing.[or][stopping]".

Check invoking while the player is drowsy:

now the player is undrowsy;

say "Han stops you. 'You've just signed the magic word. We have this unofficial color-coding process we can use that will simplify your job, but it might also ruin the magic a little bit? Once you see how this is all put together, it's kind of hard to un-see that.'[paragraph break]'Say the magic word again, and I'll augment the text with these added color-words. Say it a third time, and I'll remove the sheet and go back to normal. And so on.'";

stop the action.

Understand "select [something]" as taking. Understand "choose [something]" as taking. Understand "pick [something]" as taking. Understand "accept [something]" as taking. Understand "confirm [something]" as taking. Understand "affirm [something]" as taking.

Understand "lick [something]" as tasting.

Instead of attacking something:

say "You don't need to attack anything here; after all, you're already a skeleton."

Instead of waking up:

say "You don't sleep much anymore; after all, you're just a skeleton."

Instead of entering something (called the chair):

say "You're the presenter of this show! You can't project that kind of authority while slumped on [the chair].";

stop the action.

Pacing is an action applying to nothing. Understand "pace" as pacing. Understand "walk" as pacing. Understand "stroll" as pacing. Understand "pace thoughtfully" as pacing. Understand "skip" as pacing. Understand "pace about" as pacing. Understand "pace around" as pacing. Understand "pace about the room" as pacing. Understand "pace around the room" as pacing. Understand "walk around" as pacing.

Carry out pacing:

say "You pace[one of][or] thoughtfully[or] ponderously[or] meaningfully[or] cautiously[or] carefully[or] studiously[or] vigorously[or] fiercely[or] valiantly[or] precariously[or] implacably[or][then purely at random].";

silently try waiting.

Talking is an action applying to nothing. Understand "talk" as talking. Understand "sign" as talking. Understand "mime" as talking. Understand "pantomime" as talking.

Accosting is an action applying to one visible thing. Understand "talk to [something]" as accosting. Understand "sign to [something]" as accosting. Understand "mime to [something]" as accosting.

Instead of accosting:

try talking.

Carry out talking:

if the player is in the Present:

if the printed name of the Present is not "On the set of THIS OLD HAUNTED HOUSE":

say "Han restarts the scene. '[crisis summary of the Present]'[line break]";

stop the action;

else:

say "Han's fiddling with his notes, so he doesn't notice that you're trying to talk to him.";

stop the action;

else:

say "Han's fiddling with his notes, so he doesn't notice that you're trying to talk to him.";

stop the action.

[% I made the player a skeleton just to get out of implementing conversation. It had additional benefits, though I think I forgot to provide actual detail for the player's body and equipment...]

Instead of sleeping:

say "You don't sleep much anymore; after all, you're just a skeleton."

Instead of eating something:

say "You don't sleep much anymore; after all, you're just a skeleton."

Instead of taking inventory:

say "You're just a skeleton wearing a toolbelt, a hard hat, and protective earphones."

Instead of pushing something:

say "You don't do any actual [italic type]work[roman type]-work on this program; you don't need to push anything."

Instead of pulling something:

say "You don't do any actual [italic type]work[roman type]-work on this program; you don't need to pull anything."

Instead of turning something:

say "You don't do any actual [italic type]work[roman type]-work on this program; you don't need to turn anything."

Instead of cutting something:

say "Contractors do all the actual cutting work before you arrive, so you don't need to cut anything."

Instead of rubbing something:

say "[one of]While the need to clean is understandable, y[or]Y[stopping]ou don't need to rub that."

Instead of searching something:

say "You don't need to search anything here."

Instead of kissing something:

say "[one of]You don't have that kind of relationship with anyone or anything in this room.[or]You don't need to kiss anything here.[stopping]"

Instead of looking under something:

say "You don't need to look under anything here."

Instead of smelling:

say "[one of]Without a respiratory system to inhale with, you'd think smelling to be impossible, but you do pick up a general aroma from any space you occupy. At the moment: notes of old wood.[or]An aroma of old wood.[or]An aroma of old wood.[or]An aroma of old wood.[or]Sorry, but it's always old wood around here.[or]An aroma of old wood.[stopping]"

Instead of tasting something:

say "Hard to do that without a tongue."

Instead of jumping:

say "[one of]The ceiling isn't so low that you'd risk hitting your head, but still: b[or]B[stopping]etter not."

[% Here we get to the actions that comprise 90% of the player's activities! The verbs are again color-coded, and in "THE EXIGENT SEASONS", there are five separate actions, each of which is used in four of the ten crisis events. For "This Old Haunted House", we cut this down to two actions instead, but I left the old verbs in for some reason. In general, Hoary actions tend to be Blue, Black, and White, while Terry actions tend to be Red and Green.]

Hoarying is an action applying to nothing. Understand "hoary" as hoarying. Understand "h" as hoarying.

Terrying is an action applying to nothing. Understand "terry" as terrying. Understand "t" as terrying.

Carry out hoarying: