This Old Haunted House — 11 of 21

Book 3 - Organization of Time

Part 1 - The Crises

[% The player's decisions are presented as ten sequential scenes, once again named with color-coding to describe which two colors the player must choose between.]

A scene can be exigent or calm. A scene is usually calm. A scene has a number called the progression. The progression of a scene is usually 11.

A scene can be unresolved or resolved. A scene is usually unresolved.

A scene can be imminent or distant. A scene is usually distant.

[% Each scene works the same, and will often only be one turn long. When it's time for a particular scene to begin, the scene is changed from distant to imminent, which starts the scene. The following events occur: we set a variable to cause Han to say something instead of playing the radio, although we'll see later that if Han doesn't have anything to say, the radio plays instead. We bring the imaginary room and its contents into scope. We update the crisis summary of the present with text that will be presented as part of Han's dialogue to introduce which room the player has to make a decision about, which gets simpler as it's repeated, PLUS we present the two choices in a random order. If the magic words have been said, we include my color-code testing text.

A note about Han's room introductions: I thought players would feel that the choices and their resulting endings would be arbitrary, so I wanted to provide additional visibility to the underlying agendas that each choice represented. In "THE EXIGENT SEASONS", this comes across as Trev starting to figure things out and pointing them out to you after you've done a few rounds questions, but I probably present these a little too late for most players to see them. These details are contained in the "explainer" substitution.

Reading through these now, it's obvious I should have put each one in its own chapter or section. Maybe next time.]

White Blue is a recurring exigent scene. White Blue begins when White Blue is imminent. White Blue ends when the player carries a path.

The main hallway is a vision. Understand "the" or "main" or "hallway" or "room" or "rooms" or "hall" or "cultist" or "cultists" or "instruments" or "music" or "flickering" or "lights" or "alien" or "speech" or "sinister" or "cackling" as the main hallway.

[The workshop is a vision. Understand "the" or "forbidden" or "workshop" or "secret" or "illegal" or "laboratory" or "shop" as the workshop.

The alchemists are a vision. Understand "the" or "chemists" or "alchemists" or "chemist" or "alchemist" or "cabal" as the alchemists.]

When White Blue begins:

now HanTemp is 0;

now the main hallway is everywhere;

[now the workshop is everywhere;

now the alchemists are everywhere;]

now the crisis summary of the Present is "[the forbidden workshop][if the player is magical][azorius summary][end if]";

now the crisis term of the Present is "THE MAIN HALLWAY[if White Blue has ended] REVISITED[end if][if the player is magical] [one of](white/blue)[or](blue/white)[purely at random][end if]".

To say the forbidden workshop:

say "[one of]Almost every room in the house connects back to this hallway, so guests will return here both to get deeper into the house as well as on their way back out. That means it's ill-suited for set-pieces, but it can go a long way toward setting a mood, and this is the moment in which we'll determine what that mood is.'[paragraph break]'[forbidden workshop choices][or]The hallway could use another look.[run paragraph on][WU explainer][forbidden workshop choices][stopping]"

To say forbidden workshop choices:

say "[one of]If you take [bold type]Hoary's proposal[roman type], we're going full cosmic horror: the sounds of chanting cultists, blasphemous instruments, and alien speech will fill the hall, with lighting and décor to match. If you take [bold type]Terry's proposal[roman type] instead, we'll stick to flickering lights, groans and screams, ominous calliope music, and sinister cackling.[no line break][or]If you take [bold type]Terry's proposal[roman type], we'll stick to flickering lights, groans and screams, ominous calliope music, and sinister cackling. If you take [bold type]Hoary's proposal[roman type] instead, we're going full cosmic horror: the sounds of chanting cultists, blasphemous instruments, and alien speech will fill the hall, with lighting and décor to match.[no line break][purely at random]"

To say azorius summary:

say " (Or to put it another way, which path will you take: [one of]white or blue[or]blue or white[at random]?)[no line break]"

[% These odd names (Azorius, Simic, Rakdos, etc.) are taken directly from the Magic: the Gathering guilds that first made me want to make a color quiz. Each one corresponds to the color pair that it appears next to. I can't remember why I used guild names here, when I used color words in so many other places. I just wanted some variety, I guess...?]

To say WU explainer:

if the score is greater than a random number from 4 to 5:

say "[one of] Terry's proposal here isn't quite specific enough to count for nostalgia purposes, so the question comes down to this: would you rather embrace Hoary's cosmic horror theming, or Terry's more general creepy atmosphere?'[paragraph break]'[or] [stopping]";

else:

say " ".

White Black is a recurring exigent scene. White Black begins when White Black is imminent. White Black ends when the player carries a path.

[The poor are a vision. Understand "the" or "rest" or "room" or "restroom" or "bath" or "bathroom" or "valdaran" or "poor" or "vagabonds" or "citizens" or "pauper" or "commoners" or "paupers" or "people" or "populace" or "population" as the poor.

The lesser nobles are a vision. Understand "the" or "lesser" or "nobles" or "rivals" as the lesser nobles.

The titles are a vision. Understand "noble" or "titles" or "title" or "regalia" or "office" or "judges" or "judge" as the titles.

The riots are a vision. Understand "riot" or "riots" or "trouble" or "frenzy" as the riots.]

When White Black begins:

now HanTemp is 0;

[now the lesser nobles are everywhere;

now the titles are everywhere;

now the riots are everywhere;

now the poor are everywhere;]

now the crisis term of the Present is "THE RESTROOM[if White Black has ended] REVISITED[end if][if the player is magical] [one of](white/black)[or](black/white)[purely at random][end if]";

now the crisis summary of the Present is "[the pauper riots][if the player is magical][orzhov summary][end if]".

To say the pauper riots:

say "[one of]There's a restroom off of the main hallway, and it's positioned such that exiting the house takes visitors right by, in case they need to make use of it. Its fixtures are already adequate, but a little decorating can help it fit the overall theme so much better. Terry thought this should be a gentle wind-down experience using wind and weather atmospherics and the sounds of quiet haunting. Hoary has something more ambitious in mind: it's some kind of astral-horror set-piece with special effects that make the bathroom seem like it's floating in orbit around a blasphemous, alien planet.'[paragraph break]'[pauper riots choices][or]Shall we revisit the bathroom proposals once more?[run paragraph on][WB explainer][pauper riots choices][stopping]"

To say pauper riots choices:

say "[one of]If you take [bold type]Hoary's proposal[roman type], we'll cram the bathroom with special effects to make it seem like it's floating in space. If you instead take [bold type]Terry's proposal[roman type], we'll adjust the lighting in the bathroom and pipe in sporadic thuderstorm effects and the occasional ghostly wail.[no line break][or]If you take [bold type]Terry's proposal[roman type], we'll adjust the lighting in the bathroom and pipe in sporadic thuderstorm effects and the occasional ghostly wail. If you instead take [bold type]Hoary's proposal[roman type], we'll cram the bathroom with special effects to make it seem like it's floating in space.[no line break][purely at random]"

To say orzhov summary:

say " (Or to put it another way, which path will you take: [one of]white or black[or]black or white[at random]?)[no line break]"

To say WB explainer:

if the score is greater than a random number from 5 to 6:

say "[one of] Hoary's space nightmare scenario might be the most expensive set of special effects we've ever put together on an episode of [italic type]This Old Haunted House[roman type], which puts it in a category above simple cosmic horror, whereas Terry is going for the opposite with subtle atmospherics.'[paragraph break]'[or] [stopping]";

else:

say " ".

Blue Black is a recurring exigent scene. Blue Black begins when Blue Black is imminent. Blue Black ends when the player carries a path.

The entryway is a vision. Understand "the" or "entryway" or "windows" or "walls" or "tickets" or "people" or "graffiti" or "poltergeist" or "set-piece" or "set piece" or "set" or "piece" or "environmental" or "storytelling" or "spectral" or "manifestation" as the entryway.

[The pamphleteers are a vision. Understand "the" or "pamphleteers" or "pamphleteer" or "anarchists" or "anarchist" or "cult" or "educators" or "teachers" or "teacher" as the pamphleteers.

The populace is a vision. Understand "citizens" or "converts" or "potential" or "uneducated" or "populace" or "people" or "fools" as the populace.

The pamphlets are a vision. Understand "the" or "pamphlets" or "pamphlet" as the pamphlets.]

When Blue Black begins:

now HanTemp is 0;

now the entryway is everywhere;

[now the pamphleteers are everywhere;

now the populace is everywhere;

now the pamphlets are everywhere;]

now the crisis term of the Present is "THE ENTRYWAY[if Blue Black has ended] REVISITED[end if][if the player is magical] [one of](blue/black)[or](black/blue)[purely at random][end if]";

now the crisis summary of the Present is "[the pamphleteers][if the player is magical][dimir summary][end if]".

To say the pamphleteers:

say "[one of]Next, we need to move into the entryway. This is where people will buy their tickets, but that means that if they get cold feet here, they might chicken out before committing to the house! It presents a philosophical question: do you go minimalist, based on the fact that the people here haven't paid to see the good stuff yet, or do you go maximalist in a last-ditch effort to secure the sale? Our ghostly guests have a proposal to cover either possibility.'[paragraph break]'[pamphleteers choices][or]I want to record your entryway choice again. [run paragraph on][UB explainer][pamphleteers choices][stopping]"

To say pamphleteers choices:

say "[one of][bold type]Hoary's proposal[roman type] is to cover the walls and windows with newspapers and use graffiti to depict some terrified or desperate [']environmental storytelling.['] Or you could instead take [bold type]Terry's proposal[roman type] to spare no expense with a complex poltergeist set-piece he's calling [']the full haunting[']: a 40-minute effects program that culminates in floating furniture and a spectral manifestation.[no line break][or][bold type]Terry's proposal[roman type] is to spare no expense with a complex poltergeist set-piece he's calling [']the full haunting[']: a 40-minute effects program that culminates in floating furniture and a spectral manifestation. Or you could instead take [bold type]Hoary's proposal[roman type] to cover the walls and windows with newspapers and use graffiti to depict some terrified or desperate [']environmental storytelling.['][no line break][purely at random]"

To say dimir summary:

say " (Or to put it another way, which path will you take: [one of]blue or black[or]black or blue[at random]?)[no line break]"

To say UB explainer:

if the score is greater than a random number from 4 to 6:

say "[one of] This one's a little oblique, but Hoary's newspaper plan builds towards the psychological/cosmic horror angle he's going for in other parts of the house, while Terry's just looking to blow a big part of our budget on spectacle. Impressive, but I'm not sure we can afford to do this too many times.'[paragraph break]'[or] [stopping]";

else:

say " ".

Blue Red is a recurring exigent scene. Blue Red begins when Blue Red is imminent. Blue Red ends when the player carries a path.

The kitchen is a vision. Understand "counter" or "counters" or "table" or "tables" or "cabinet" or "cabinets" or "fridge" or "refrigerator" or "the" or "cannibal" or "cryptid" or "organ" or "organs" or "blood" or "bloody" or "butcher" as the kitchen.

[The noble is a vision. Understand "the" or "wealthy" or "noble" or "decedent" or "patron" as the noble.

The estate is a vision. Understand "the" or "gold" or "coins" or "inheritance" or "treasure" or "funding" as the estate.

A vision called the Valdaran Conservatory of Learning and the Arts is nowhere. Understand "valdaran" or "conservatory" or "of" or "learning" or "the" or "arts" or "and" or "institution" or "school" or "college" or "academy" or "beneficiary" or "heir" as the Valdaran Conservatory of Learning and the Arts.

Art is a vision. Understand "cultural" or "enrichment" or "new" or "works" or "performances" or "art" as art.

Science is a vision. Understand "practical" or "matters" or "new" or "tools" or "techniques"as science.]

When Blue Red begins:

now HanTemp is 0;

now the kitchen is everywhere;

[now the noble is everywhere;

now the estate is everywhere;

now the Valdaran Conservatory of Learning and the Arts is everywhere;

now art is everywhere;

now science is everywhere;]

now the crisis term of the Present is "THE KITCHEN[if Blue Red has ended] REVISITED[end if][if the player is magical] [one of](blue/red)[or](red/blue)[purely at random][end if]";

now the crisis summary of the Present is "[the disputed patronage][if the player is magical][izzet summary][end if]".

To say the disputed patronage:

say "[one of]The kitchen follows the dining room, which runs a risk of feeling like [']more of the same['], so think about whether you'd prefer to double up on an earlier theme, or introduce a change of pace.'[paragraph break]'Terry's continuing his cannibal approach here, introducing a bloody butcher character to show off all his wares: intestines, eyeballs, things like that. Hoary's design focuses more on the fear of the unknown, stocking the kitchen with alien ingredients, cryptid components, and the food man was not meant to know of.'[paragraph break]'[disputed patronage choices][or]Let's consider the cannibal or cosmic-horror kitchen.[run paragraph on][UR explainer][disputed patronage choices][stopping]"

To say disputed patronage choices:

say "[one of]If you accept [bold type]Hoary's proposal[roman type], your kitchen will overflow with strange and supernatural substances. If you instead accept [bold type]Terry's proposal[roman type], the butcher will set up his organ-trade here.[no line break][or]If you accept [bold type]Terry's proposal[roman type], the butcher will set up his organ-trade here. If you instead accept [bold type]Hoary's proposal[roman type], your kitchen will overflow with strange and supernatural substances.[no line break][purely at random]"

To say izzet summary:

say " (Or to put it another way, which path will you take: [one of]blue or red[or]red or blue[at random]?)[no line break]"

To say UR explainer:

if the score is greater than a random number from 6 to 8:

say "[one of] So this one's pretty obvious: Terry's most powerful works capitalize on his skill with the gory aesthetic, while Hoary's a master of supernatural horror. No matter which route you go, you'll be playing to one of the brothers['] strengths... unless you take neither option and present a typical kitchen. That could be sort of scary, depending on what people just witnessed in the dining room.'[paragraph break]'[or] [stopping]";

else:

say " ".

Black Red is a recurring exigent scene. Black Red begins when Black Red is imminent. Black Red ends when the player carries a path.

The dining room is a vision. Understand "the" or "dining" or "room" or "table" or "chairs" or "cannibal's" or "cannibal" or "feast" or "goblet" or "goblets" or "blood" or "organs" or "head" or "heads" or "piano" or "serving" or "dish" as the dining room.

[The Unblinking Eye is a vision. Understand "the" or "unblinking" or "eye" or "unofficial" or "group" or "reliable" or "informants" or "turncoats" or "tattletales" or "snitches" or "constables" or "constable" or "secret" or "police" as the Unblinking Eye.

The citizens are a vision. Understand "the" or "paranoid" or "citizens" as the citizens.]

When Black Red begins:

now HanTemp is 0;

now the dining room is everywhere;

[now the Unblinking Eye is everywhere;

now the citizens are everywhere;]

now the crisis term of the Present is "THE DINING ROOM[if Black Red has ended] REVISITED[end if][if the player is magical] [one of](black/red)[or](red/black)[purely at random][end if]";

now the crisis summary of the Present is "[the unblinking eye][if the player is magical][rakdos summary][end if]".

To say the unblinking eye:

say "[one of]Now that we're moving into the parts of the house that have to do with food, things are likely to get messy. First up, we've got the dining room, where Terry's predictable appetites are on display, but Hoary has an unconventional choice you might prefer. I'll be interested to see your preference here.'[paragraph break]'[unblinking eye choices][or]So: the dining room.[run paragraph on][BR explainer][unblinking eye choices][stopping]"

To say unblinking eye choices:

say "[one of][bold type]Hoary's proposal[roman type] skips the dining theme entirely in favor of installing a grand piano on one side of the room which will chomp its lid in a furious and memorable fashion. But if you instead accept [bold type]Terry's proposal[roman type], we'll lay out a cannibal's feast, goblets full of blood, and the occasional serving dish containing a talking head.[no line break][or]With [bold type]Terry's proposal[roman type], we'll lay out a cannibal's feast, goblets full of blood, and the occasional serving dish containing a talking head. But if you instead accept [bold type]Hoary's proposal[roman type] we'll skip the dining theme entirely in favor of installing a grand piano on one side of the room which will chomp its lid in a furious and memorable fashion.[no line break][purely at random]"

To say rakdos summary:

say " (Or to put it another way, which path will you take: [one of]black or red[or]red or black[at random]?)[no line break]"

To say BR explainer:

if the score is greater than a random number from 5 to 6:

say "[one of] It's not as explicit as some of his other proposals, but what Terry's offering here is still on the gory side. Oh, and have we talked about how expensive it would be to build a grand piano that can angrily chomp at people?'[paragraph break]'[or] [stopping]";

else:

say " ".

Black Green is a recurring exigent scene. Black Green begins when Black Green is imminent. Black Green ends when the player carries a path.

The child's bedroom is a vision. Understand "the" or "child" or "child's" or "childs" or "children" or "children's" or "childrens" or "doll" or "dolls" or "marionette" or "puppet" or "dollhouse" or "freddie" or "fazbear" or "animatronic" or "robot" or "killer" as the child's bedroom.

[The mutineers are a vision. Understand "the" or "mutineers" or "citizens" or "sailors" or "mutinous" as the mutineers.

The suzerain state is a vision. Understand "the" or "suzerain" or "state" or "suzerainty" or "navy" or "navies" or "overseers" or "empire" as the suzerain state.

The Valdaran docks are a vision. Understand "seas" or "high" or "ship" or "ships" or "harbor" or "Valdaran" or "docks" or "harbormaster" or "master" or "dockmaster" as the Valdaran docks.

Understand "Valdaran" or "Valdarans" or "the" or "people" or "citizens" or "sailors" as the citizens.]

When Black Green begins:

now HanTemp is 0;

now the child's bedroom is everywhere;

[now the mutineers are everywhere;

now the suzerain state is everywhere;

now the Valdaran docks are everywhere;

now the citizens are everywhere;]

now the crisis term of the Present is "THE CHILD'S BEDROOM[if Black Green has ended] REVISITED[end if][if the player is magical] [one of](black/green)[or](green/black)[purely at random][end if]";

now the crisis summary of the Present is "[the mutineers][if the player is magical][golgari summary][end if]".

To say the mutineers:

say "[one of]Our first stop in the progression of bedrooms is a child's room. We don't want to go too dark here, so we've asked our consultants to provide a lighter touch with their proposals this time. Terry has a very traditional idea with dolls that I think you'll find appealing, but Hoary's thinking bigger. Kids love those horror games with name-brand animatronics-gone-bad, and he suggests we could pay a little extra to bring one of those famous names on board with a crossover set-piece. '[paragraph break]'[mutineers choices][or]How shall we outfit the kid's room?[run paragraph on][BG explainer][mutineers choices][stopping]"

To say mutineers choices:

say "[one of]Pick [bold type]Hoary's proposal[roman type] to splurge on a brand-name killer animatronic robot for tween appeal. Pick [bold type]Terry's proposal[roman type] to fill the room with creepy dolls, haunted dollhouses, scary marionettes, and similar residents of the uncanny valley.[no line break][or]Pick [bold type]Terry's proposal[roman type] to fill the room with creepy dolls, haunted dollhouses, scary marionettes, and similar residents of the uncanny valley. Pick [bold type]Hoary's proposal[roman type] to splurge on a brand-name killer animatronic robot for tween appeal.[no line break][purely at random]"

To say golgari summary:

say " (Or to put it another way, which path will you take: [one of]black or green[or]green or black[at random]?)[no line break]"

To say BG explainer:

if the score is greater than a random number from 6 to 7:

say "[one of] Going with the crossover animatronics is a pricy prospect, but it doesn't push you toward a particular theme the way that the doll stuff pushes you toward [']traditional['] Halloween aesthetics.'[paragraph break]'[or] [stopping]";

else:

say " ".

Red Green is a recurring exigent scene. Red Green begins when Red Green is imminent. Red Green ends when the player carries a path.

The parlor is a vision. Understand "sitting" or "room" or "flailing" or "limbs" or "zombies" or "zombie" or "boards" or "windows" or "chainsaw" or "maniac" or "blood" or "shrieking" or "teenagers" as the parlor.

[Daggers are a vision. Understand "the" or "daggers" or "dagger" or "knife" or "knives" as daggers.

Moral leaders are a vision. Understand "moral" or "leaders" as moral leaders.

Knife-wounds are a vision. Understand "knife-wounds" or "knife-wound" or "knife wound" or "knife wounds" or "finger" or "fingers" as knife-wounds.]

When Red Green begins:

now HanTemp is 0;

now the parlor is everywhere;

[now daggers are everywhere;

now moral leaders are everywhere;

now knife-wounds are everywhere;

now the citizens are everywhere;]

now the crisis term of the Present is "THE PARLOR[if Red Green has ended] REVISITED[end if][if the player is magical] [one of](red/green)[or](green/red)[purely at random][end if]";

now the crisis summary of the Present is "[daggers][if the player is magical][gruul summary][end if]".

To say daggers:

say "[one of]Our first stop after ticketing is the parlor, a sitting room for entertaining guests, so this is where we can demonstrate to our patrons just what they're paying for. Let's make it big!'[paragraph break]'[daggers choices][or]Let's revisit the parlor proposals.[run paragraph on][RG explainer][daggers choices][stopping]"

To say daggers choices:

say "[one of]In [bold type]Hoary's proposal[roman type], we board up the windows and set up your classic zombie siege scenario with flailing limbs, only to turn the tables with the surprise arrival of a chainsaw maniac inside the room, scaring the visitors into the zombies['] clammy grasp. In [bold type]Terry's proposal[roman type], we deck out the room for a slasher-movie sleep-over, heavy on the simulated blood-spray and shrieking teenagers.[no line break][or]In [bold type]Terry's proposal[roman type], we deck out the room for a slasher-movie sleep-over, heavy on the simulated blood-spray and shrieking teenagers. In [bold type]Hoary's proposal[roman type], we board up the windows and set up your classic zombie siege scenario with flailing limbs, only to turn the tables with the surprise arrival of a chainsaw maniac inside the room, scaring the visitors into the zombies['] clammy grasp.[no line break][purely at random]"

To say gruul summary:

say " (Or to put it another way, which path will you take: [one of]red or green[or]green or red[at random]?)[no line break]"

To say RG explainer:

if the score is greater than a random number from 5 to 8:

say "[one of] We're committed to spending money on this, so don't worry about which one seems more expensive. Technically, both of these proposals are more Terry's style, but Hoary can roll with a classic trope like zombies when the alternative's so heavy on the blood effects.'[paragraph break]Hoary nods.[paragraph break]'[or] [stopping]";

else:

say " ".

Red White is a recurring exigent scene. Red White begins when Red White is imminent. Red White ends when the player carries a path.

The guest room is a vision. Understand "the" or "guest" or "room" or "bed" or "cabinet" or "window" or "windows" or "weather" or "lighting" or "police" or "tape" or "shattered" or "windows" or "sirens" or "flashing" or "lights" or "crime" or "scene" as the guest room.

[The squatters are a vision. Understand "the" or "squatters" or "squatter" or "poor" or "homeless" or "peasants" or "tenant" or "tenants" as the squatters.

The nobles are a vision. Understand "nobles" or "noble" or "landlords" or "landlord" or "lords" as the nobles.

The buildings are a vision. Understand "land" or "acreage" or "unoccupied" or "buildings" as the buildings.]

When Red White begins:

now HanTemp is 0;

[now the squatters are everywhere;

now the nobles are everywhere;

now the buildings are everywhere;]

now the crisis term of the Present is "THE GUEST ROOM[if Red White has ended] REVISITED[end if][if the player is magical] [one of](red/white)[or](white/red)[purely at random][end if]";

now the crisis summary of the Present is "[the squatters][if the player is magical][boros summary][end if]".

To say the squatters:

say "[one of]We've conceptualized the second bedroom as a guest room, and having already established the dangers that the house itself contains, it seems very unlikely that any houseguest is going to have a good time. But which is spookier: the anticipation of not knowing just what might happen here, or the grisly aftermath of a heinous act?'[paragraph break]'[squatters choices][or]Let's revisit the guest room.[run paragraph on][RW explainer][squatters choices][stopping]"

To say squatters choices:

say "[one of]To build up a dreadful atmosphere with stormy weather, ominous music, strange lighting, and the sounds of muffled cries and sinister laughter, accept [bold type]Hoary's proposal[roman type]. To instead build a horrific crime-scene tableau with police tape, shattered windows, sirens and flashing lights, and troubling body-shapes wrapped in bloodstained sheets, accept [bold type]Terry's proposal[roman type].[no line break][or]To build a horrific crime-scene tableau with police tape, shattered windows, sirens and flashing lights, and troubling body-shapes wrapped in bloodstained sheets, accept [bold type]Terry's proposal[roman type]. To instead build up a dreadful atmosphere with stormy weather, ominous music, strange lighting, and the sounds of muffled cries and sinister laughter, accept [bold type]Hoary's proposal[roman type].[no line break][purely at random]"

To say boros summary:

say " (Or to put it another way, which path will you take: [one of]white or red[or]red or white[at random]?)[no line break]"

To say RW explainer:

if the score is greater than a random number from 6 to 8:

say "[one of] Going with pure atmospherics might seem strange the late in the tour, but that doesn't make it a bad idea. If you've made a lot of bloodthirsty selections in other parts of the house, you might go the opposite direction here if you want to balance things out.'[paragraph break]'[or] [stopping]";

else:

say " ".

Green White is a recurring exigent scene. Green White begins when Green White is imminent. Green White ends when the player carries a path.

The yard is a vision. Understand "lawn" or "yard" or "grass" or "graves" or "pumpkins" or "spiders" or "spiderwebs" or "spiderweb" or "grave" or "gravestone" or "gravestones" or "front" or "the" or "windows" or "roof" or "recordings" or "outside" or "street" or "houses" or "line" or "lighting" or "effects" as the yard.

[The famine is a vision. Understand "the" or "famine" or "starvation" or "hunger" as the famine.

Understand "house" or "houses" or "wealthy" or "wealth" as the nobles.

Food is a vision. Understand "food" or "supply" or "supplies" or "grains" or "meats" as food.]

When Green White begins:

now HanTemp is 0;

now the yard is everywhere;

[now the famine is everywhere;

now the nobles are everywhere;

now the citizens are everywhere;

now food is everywhere;]

now the crisis term of the Present is "THE FRONT LAWN[if Green White has ended] REVISITED[end if][if the player is magical] [one of](green/white)[or](white/green)[purely at random][end if]";

now the crisis summary of the Present is "[the famine][if the player is magical][selesnya summary][end if]".

To say the famine:

say "[one of]Terry insists that outdoor spaces need to overwhelm the senses and demand the viewer make sense of the layers of visual complexity. Hoary by contrast, prefers not to overcommit at this early stage. He favors using oblique elements to establish a spooky mood and prime our visitors for the frights to come. Let's see how Bone feels about their proposals.'[paragraph break]'[famine choices][or]Let's run the front yard proposals again.[run paragraph on][GW explainer][famine choices][stopping]"

To say famine choices:

say "[one of][bold type]Hoary's proposal[roman type] uses fog machines, recordings of crows and wolves, and subtle lighting effects to set guests['] expectations. [bold type]Terry's proposal[roman type] would transform the lawn into an overwrought graveyard with plenty of pumpkins and spiderwebs to go around.[no line break][or][bold type]Terry's proposal[roman type] would transform the lawn into an overwrought graveyard with plenty of pumpkins and spiderwebs to go around. [bold type]Hoary's proposal[roman type] uses fog machines, recordings of crows and wolves, and subtle lighting effects to set guests['] expectations.[no line break][purely at random]"

To say selesnya summary:

say " (Or to put it another way, which path will you take: [one of]white or green[or]green or white[at random]?)[no line break]"

To say GW explainer:

if the score is greater than a random number from 5 to 7:

say "[one of] If it's not already obvious, Terry's proposal is a big draw for the classic nostalgia crowd, while Hoary is trying to maximize atmospherics.' The Boo-thers bob in agreement.[paragraph break]'[or] [stopping]";

else:

say " ".

Green Blue is a recurring exigent scene. Green Blue begins when Green Blue is imminent. Green Blue ends when the player carries a path.

[The pox is a vision. Understand "the" or "pox" or "illness" or "disease" or "plague" or "virus" or "epidemic" as the pox.

The healers are a vision. Understand "the" or "your" or "my" or "healer" or "healers" or "doctor" or "doctors" or "plague" as the healers.

The poxed bodies are a vision. Understand "the" or "body" or "bodies" or "corpse" or "corpses" or "citizens" as the poxed bodies.]

When Green Blue begins:

now HanTemp is 0;

[now the pox is everywhere;

now the healers are everywhere;

now the poxed bodies are everywhere;]

now the crisis summary of the Present is "[the pox][if the player is magical][simic summary][end if]";

now the crisis term of the Present is "THE MASTER BEDROOM[if Green Blue has ended] REVISITED[end if][if the player is magical] [one of](green/blue)[or](blue/green)[purely at random][end if]".

To say the pox:

say "[one of]Our final bedroom should be the climax of the tour. It's time to pay off those tropes you've been building up so far. This will be one of the historic showdowns: the sympathetic villain versus the tragic hero.'[paragraph break]'[pox choices][or]The master bedroom! What are we thinking?[run paragraph on][GU explainer][pox choices][stopping]"

To say pox choices:

say "[one of][bold type]Hoary's proposal[roman type] showcases the descent into madness of your supernatural horror protagonist with conspiracy corkboards, musty tomes, ritual weapons, and the fanatical conviction of our doomed [']hero['] actor. Or perhaps you'd prefer [bold type]Terry's proposal[roman type], which converts the bedroom into the lair of the master vampire, complete with coffin, goblets, gothic accoutrements, and the alluring monster himself.[no line break][or][bold type]Terry's proposal[roman type] converts the bedroom into the lair of the master vampire, complete with coffin, goblets, gothic accoutrements, and the alluring monster himself. Or perhaps you'd prefer [bold type]Hoary's proposal[roman type], which showcases the descent into madness of your supernatural horror protagonist with conspiracy corkboards, musty tomes, ritual weapons, and the fanatical conviction of our doomed [']hero['] actor.[no line break][purely at random]"

To say simic summary:

say " (Or to put it another way, which path will you take: [one of]green or blue[or]blue or green[at random]?)[no line break]"

To say GU explainer:

if the score is greater than a random number from 4 to 8:

say "[one of] Despite the thematic relation to blood, Terry's vampire scenario won't make the house seem gorier than it already is. It's too familiar for that.'[paragraph break]'[or] [stopping]";

else:

say " ".

When a scene (called the postlude) which is exigent ends:

now every path is nowhere;

now the postlude is resolved;

repeat through the Table of Seasonal Progression in reverse order:

if the Emergency entry is unresolved:

now every scene is distant;

now the Emergency entry is imminent;

if every scene is distant:

now the player is in the End of Exigencies.

When a scene (called the prelude) which is imminent begins:

now the prelude is distant;

choose row with Crisis of prelude in the Table of Critical Components;

now the option three entry is in the Present;

now the option one entry is in the Present;

now the option two entry is in the Present;

[try showing ranks; [$$$ This should be commented out before release.]]

now every path is undescribed.

To Check the Seasons: [$$$ This should be commented out before release.]

say "The Table of Seasonal Progression is as follows...";

repeat through the Table of Seasonal Progression:

say "[Sequence entry]: [Emergency entry]."

[% Hey, why didn't I just put this in a Not For Release section?? And more importantly, why didn't I comment it out before release?!]

Table of Seasonal Progression

To Check the Components: [$$$ This should be commented out before release.]

say "[line break]The Table of Critical Components is as follows...";

repeat through the Table of Critical Components:

say "[Sequentializer entry]: [Crisis entry]."

[% I think these were testing tools I had to add when the order of rooms wasn't occurring consistently. Not sure if it's actually a problem that I didn't remove them, though.]

Table of Critical Components