Jason Love

Part 3 - New Actions

Fullscoring is an action out of world. Understand "full" and "fullscore" and "full score" as fullscoring.

Report fullscoring:

say "You reviewed [score in words] ending[s] out of a possible [maximum score in words] before you embarked on your final path.";

carry out the Reciting Endings activity.

Abouting is an action out of world. Understand "about" and "info" as abouting.

Report abouting: say "In this game, your friend Trev is obsessed with a magazine quiz and wants to see how many endings you can get before you both get bored. Only three commands are required: [bold type]WAIT[roman type] (or [bold type]Z[roman type]) will give Trev the time he needs to prepare questions or calculate endings; [bold type]TAKE[roman type] will allow you to select from the paths he offers; finally, [bold type]LEAVE[roman type] will communicate your boredom to Trev and let you end the game. (If you ever need Trev to repeat the current crisis description, just [bold type]TALK[roman type] to him.) To track your progress, you can use [bold type]SCORE[roman type] for a simple count of the endings you've discovered, or [bold type]FULLSCORE[roman type] for a more detailed list[one of].[or]. You may also prefer to obtain [bold type]HELP[roman type], get a [bold type]HINT[roman type], or if all else fails, you can [bold type]CHEAT[roman type] if the quiz isn't holding your interest.[stopping][line break]Please send me any feedback, bug reports, or transcripts to JSNLXNDRLV@GMAIL.COM. Version 2 of the game, which includes improved improved text and fewer adverbs, still listed the version number as 1. Version number 2 is identical, with the exception of these two sentences and the inclusion of the source code on the website."; try crediting.

Crediting is an action out of world. Understand "credits" and "testers" as crediting.

Report crediting: say "This game makes use of the following extensions:[line break][bold type][the complete list of extension credits][roman type][line break]Dozens of people deserve thanks for helping me refine my thinking and turn this program into something functional, but I should recognize [bold type]Jenni Polodna[roman type] and [bold type]Ryan Veeder[roman type] for their [italic type]Cragne Manor[roman type] project, to say nothing of the other [italic type]Cragne[roman type] contributors, many of whom answered my implementation questions in the community Slack channels.[paragraph break]I owe further thanks to the users of Select Button Dot Net, foremost among them user [bold type]nettle[roman type], who got me moving on this again after I stalled out for more than a year.[paragraph break]Additional thanks go to [bold type]nettle[roman type], [bold type]Gate88[roman type], and [bold type]Zaratustra[roman type] for testing earlier versions of this game, but I've left a few bugs in this version just so that [bold type]you[roman type] would have the opportunity to be included in this list! Just point out such a bug in an email to (again) JSNLXNDRLV@GMAIL.COM.[paragraph break]I generated the cover art image using Katherine Crowson's VQGAN+CLIP running on a Google Collab Notebook set up by Eleiber and Abulafia and translated into English by @somewheresy; I created the magazine formatting using Canva.[paragraph break]You may also wish to read the [bold type]DEDICATION[roman type][one of].[or] or the [bold type]CONTROVERSION[roman type].[stopping]".

Dedication is an action out of world. Understand "dedication" as dedication.

Report dedication: say "[italic type][Story title][roman type] is dedicated to [bold type]Julie Love[roman type], who groans whenever she notices that I've typed more than a paragraph."

Controversion is an action out of world. Understand "controversion" as controversion.

Report controversion: say "[italic type][Story title][roman type] is controverted to [bold type]Carl Dutcher[roman type], who sees no flaws or errors where he really ought to see many."

Helping is an action out of world. Understand "help" and "walkthrough" and "walkthru" as helping.

Report helping: say "Trev's article tells a story in which you rule a city-state facing a series of crises. As each crisis appears, your advisors will identify two potential paths forward. You must select which of these paths is your preference; while they are not opposites, they are mutually[one of] exclusive. Regardless[or] exclusive. (However, you're not [italic type]required[roman type] to choose one of the described paths; you could instead select neither.) Regardless[stopping] of your selection, this particular crisis will pass, and another will present itself in the next season. The selections you make will set in motion unseen trends among your populace, and once every crisis is finished, you will be informed what future your choices have brought about. [one of][or]By proceeding through this process to see various futures, you and Trev may pass the time in comparative entertainment.[stopping][paragraph break]Frequent players may prefer to abbreviate commands; for example, shorten 'TAKE AWKWARD PATH' to simply 'AWKWARD'.[paragraph break]If you are having trouble reaching new endings, you can ask for a HINT[one of][or] or just CHEAT to skip the quiz and look up a random ending instead[stopping]. You can TALK TO TREV to have him describe the current crisis again."

A person can be drowsy or undrowsy. When play begins, now the player is drowsy.

Xyzzying is an action out of world. Understand "xyzzy" as xyzzying. Understand "plugh" as xyzzying. Understand "plover" as xyzzying.

Carry out xyzzying:

say "[one of]That isn't a verb I recognize.[line break][or]That isn't a verb I recognize.[line break][or]That isn't a verb I recognize.[line break][or]That isn't a verb I recognize.[line break][or]That isn't a verb I recognize.[line break][or]That isn't a verb I recognize.[line break][or]That isn't a verb I recognize.[line break][or]That isn't a verb I recognize.[line break][or]Maybe try saying that backwards, instead?[line break][as decreasingly likely outcomes]".

[While the intention is that players won't know about the magic words until after getting the amusing text from the ending, I've changed the contraction of the error response here so that attentive players will notice the oddity and potentially investigate further, possibly getting the unlikely clue to put the word in backwards instead.]

Invoking is an action out of world. Understand "vaadignephod" as invoking. Understand "say vaadignephod" as invoking. Understand "invoke vaadignephod" as invoking. Understand "invoke" as invoking. Understand "invoke the name vaadignephod" as invoking. Understand "presto" as invoking. Understand "presto changeo" as invoking. Understand "abracadabra" as invoking. Understand "yzzyx" as invoking. Understand "hgulp" as invoking. Understand "revolp" as invoking. Understand "invoke name" as invoking. Understand "alakazam" as invoking. Understand "abra cadabra" as invoking. Understand "hocus pocus" as invoking. Understand "hey presto" as invoking. Understand "please" as invoking. Understand "thank you" as invoking.

Carry out invoking:

if the player is mundane:

now the player is magical;

say "Trev [first time]raises his eyebrows, but says nothing. He [only]removes a transparent overlay from the back of the magazine and settles it over the page.";

otherwise:

now the player is mundane;

say "Trev [first time]sighs. 'Okay, okay, enough with the magic words, I get it.' He [only]removes the text overlay and puts it back at the end of the magazine."

Check invoking while the player is drowsy:

now the player is undrowsy;

say "Trev stops you. 'You've just said the magic word. It's not an official part of the article, but I have this plastic sheet that I can lay on top of the text to add some color-coding to the quiz. This will make it easier choose paths for the purpose of achieving a particular ending, but it might also ruin the magic a little bit? Once you see how this is all put together, it's kind of hard to un-see that.'[paragraph break]'Say the magic word again, and I'll augment the text with these added color-words. Say it a third time, and I'll remove the sheet and go back to normal. And so on.'";

stop the action.

Understand "select [something]" as taking. Understand "choose [something]" as taking. Understand "pick [something]" as taking.

Understand "lick [something]" as tasting.

Instead of attacking something:

say "[one of]You're not about to attack something, at least not outside your roleplaying session.[or]You don't need to attack anything.[stopping]"

Instead of waking up:

say "[one of]It's tough to shake off this drowsiness, but you'll perk up once everybody else shows up. You can pace until then.[or]You're waking up enough as it is.[stopping]"

Instead of entering something (called the chair):

say "[one of]Sure, you [italic type]could[roman type] try sitting on [the chair], but then you wouldn't be able to pace thoughtfully about the room while considering the exigence of all these seasons.[or]You're not going to sit on anything right now.[stopping]";

stop the action.

Pacing is an action applying to nothing. Understand "pace" as pacing. Understand "walk" as pacing. Understand "stroll" as pacing. Understand "pace thoughtfully" as pacing. Understand "skip" as pacing. Understand "pace about" as pacing. Understand "pace around" as pacing. Understand "pace about the room" as pacing. Understand "pace around the room" as pacing. Understand "walk around" as pacing.

Carry out pacing:

say "You pace[one of][or] thoughtfully[or] ponderously[or] meaningfully[or] cautiously[or] carefully[or] studiously[or] vigorously[or] fiercely[or] valiantly[or] precariously[or] implacably[or][then purely at random].";

silently try waiting.

Talking is an action applying to nothing. Understand "talk" as talking.

Accosting is an action applying to one visible thing. Understand "talk to [something]" as accosting.

Instead of accosting:

try talking.

Carry out talking:

if the player is in the Present:

if the printed name of the Present is not "PREGAMING IN TREV'S BASEMENT":

say "Trev repeats himself. '[crisis summary of the Present]'[line break]";

stop the action;

else:

say "Trev is still getting ready, so he doesn't hear you.";

stop the action;

else:

say "Trev's too busy with the magazine and his notes.";

stop the action.

Instead of sleeping:

if the player is in the Present:

if NEITHER is not in the Present:

say "You've crashed at Trev's before, but you're not quite that tired yet.";

if NEITHER is in the Present:

say "[one of]You indicate your disinterest in the options presented with cartoonishly overblown snoring. Trev cackles.[or]You make another snoring sound. Trev makes a note.[stopping]";

silently try taking NEITHER;

if the player is in the Future, say "You've crashed at Trev's before, but you're not [bold type]that[roman type] tired right now."

Instead of eating something:

say "[one of]Nothing currently in Trev's basement should be considered edible. [italic type]Especially[roman type] the food.[or]You shouldn't eat anything here.[stopping]"

Instead of taking inventory:

say "[one of]All your stuff's upstairs until the rest of the group arrives.[or]You don't have anything on you at the moment.[stopping]"

Instead of pushing something:

say "[one of]All Trev's stuff is precarious enough as it is; y[or]Y[stopping]ou don't need to push that."

Instead of pulling something:

say "[one of]All Trev's stuff is precarious enough as it is; y[or]Y[stopping]ou don't need to pull that.."

Instead of turning something:

say "[one of]All Trev's stuff is precarious enough as it is; y[or]Y[stopping]ou don't need to turn that."

Instead of cutting something:

say "[one of]All Trev's stuff is precarious enough as it is; y[or]Y[stopping]ou don't need to cut that."

Instead of rubbing something:

say "[one of]While the need to clean is understandable, y[or]Y[stopping]ou don't need to rub that."

Instead of searching something:

say "[one of]The only thing you need to search is your soul: how are you going to get through these exigent seasons?[or]You don't need to search anything here.[stopping]"

Instead of kissing something:

say "[one of]You don't have that kind of relationship with anyone or anything in this room.[or]You don't need to kiss anything here.[stopping]"

Instead of looking under something:

say "[one of]Trev's basement is the kind of place where things that fall under other things are better left forgotten.[or]You don't need to look under anything here.[stopping]"

Instead of smelling:

say "[one of]You've been to Trev's place often enough to achieve a level of nose-blindness to the local ambience, but that's no reason to borrow trouble.[or]You shouldn't smell anything here.[stopping]"

Instead of tasting something:

say "[one of]Impossibly reckless. Never try to taste anything here again.[or][foolishness][stopping]"

To say foolishness:

say "You should have known better than to touch your tongue to anything in this area.";

end the story saying "You invited [one of]Streptococcus[or]Campylobacter[or]Escherichia coli[purely at random] into your body".

Instead of jumping:

say "[one of]The ceiling isn't so low that you'd risk hitting your head, but still: b[or]B[stopping]etter not."

Whiting is an action applying to nothing. Understand "white" as whiting. Understand "justice" as whiting. Understand "democratic" as whiting. Understand "nobility" as whiting. Understand "coin purse" as whiting. Understand "coin" as whiting. Understand "purse" as whiting.

Carry out whiting: